単純な表ならデータタブのWebからでできるのですが、最近は取り込めない場合もあるようです。

もしテキストファイルで配布されているのであれば、データタブのデータの取得の中のテキストファイルとかでURLを指定して取り込めばいいのではないかと思います。

これらで取り込んだものは、リアルタイムでは更新されないのですが、そのブックを開いたタイミングで読み込み自動で更新してくれます。

ただこれらの方法で取り込めない時もたくさんあるので、そうなってくるとVBAで取り込む必要も出てきます。

でもVBAで作ればそれなりにコストもかかるでしょうから、その前にWEBSERVICE関数とかFILTERXML関数とかでなんとかできないか考えてみたほうがいいでしょう。

金融市場のカレンダーでしたらJPX（東証）のサイトの情報が信頼できるのではないでしょうか？

https://www.jpx.co.jp/corporate/about-jpx/calendar/

VBAでこのカレンダーから祝日のリストを取得するには、次のステップで行います。

1. JPXのサイトをスクレイピング
2. DOMを解析
3. 日付をExcelに貼り付け

1. JPXのサイトをスクレイピング

VBAでウェブサイトに接続してデータを取得する方法はいくつかありますが、「MSXML2.XMLHTTP」オブジェクトを利用するのが手軽だと思います。

Dim http: Set http = CreateObject("MSXML2.XMLHTTP")
http.Open "GET", "https://www.jpx.co.jp/corporate/about-jpx/calendar/", False
http.send
Dim res: res = http.responseText

以上で、変数resにはJPXのサイトから取得したHTML文字列が格納されます。

2. DOMを解析

次に取得したHTMLから目的となる休日データを抽出します。VBAでHTMLを解析するには「MSHTML.HTMLDocument（htmlfile）」オブジェクトを利用するのが便利です。

Dim doc: Set doc = CreateObject("htmlfile")
doc.write res

これだけで、文字列のHTMLがパースされHTMLDocumentオブジェクトとして扱えるようになります。

3. 日付をExcelに貼り付け

最後に、HTMLDocumentオブジェクトを通じて日付情報を取得し、Excelのシートに出力します。今回はA列の一番上のセルから下方向に日付を入力していきます。

Dim i As Integer: i = 1
Dim table
For Each table In doc.getElementsByTagName("table")
    Dim tr
    For Each tr In table.getElementsByTagName("tr")
        Dim d: d = Left(tr.FirstChild.innerText, 10)
        If IsDate(d) Then
            Cells(i, 1).Value = CDate(d)
            i = i + 1
        End If
    Next
Next

まず、HTMLに含まれるテーブル（table）要素を抽出し、For Eachを使って一つ一つ処理します。そして、それぞれのテーブルに対して、テーブルに含まれる行（tr）要素を同様に抽出します。日付はtr要素の最初の子要素であるtd要素に含まれているので、FirstChild.innerTextによってその値を取得することができます。

取得した日付は「2019/01/01（火）」という形式になっていますので、Left関数を使って曜日以外の部分を抽出します。そして、IsDate関数を使って日付形式として正しいかどうかをチェックした上で、CDate関数を使って文字列としての日付を日付形式に変換しています。最後にA列のセルにその値を設定して終わりです。

全体のコードは次になります。

Option Explicit

Sub GetHolidays()

    'JPXのサイトをスクレイピング
    Dim http: Set http = CreateObject("MSXML2.XMLHTTP")
    http.Open "GET", "https://www.jpx.co.jp/corporate/about-jpx/calendar/", False
    http.send
    Dim res: res = http.responseText

    'DOMを解析
    Dim doc: Set doc = CreateObject("htmlfile")
    doc.write res

    '日付をExcelに貼り付け
    Dim i As Integer: i = 1
    Dim table
    For Each table In doc.getElementsByTagName("table")
        Dim tr
        For Each tr In table.getElementsByTagName("tr")
            Dim d: d = Left(tr.FirstChild.innerText, 10)
            If IsDate(d) Then
              Cells(i, 1).Value = CDate(d)
              i = i + 1
            End If
        Next
    Next
End Sub

※この投稿は祝日カレンダーをVBAを使って取得する技術的な方法を紹介するが目的です。実際にプログラムを使ってJPXサイトからデータを取得することの可否はJPX社にお尋ねください。